Teil 1 - Eine neue Formel zur Darstellung von Raumschüssen im Längsschnitt

Im Juni 2019 ist mir aufgefallen, dass die Formel, die zur Berechnung der Darstellung von Raumschüssen / Hilfsmesszügen im Längsschnitt verwendet wird, manchmal zu einer sehr verzerrten Darstellung führt.
Ich brauchte einen ganzen Monat, um auf der Basis der alten Formel eine neue zu entwickeln und benutze sie seither für alle meine Höhlenpläne. Bisher habe ich mich nicht getraut, hier davon zu berichten, denn ich war mir nicht sicher, ob meine Lösung wirklich mathematisch richtig ist und nicht nur eine bessere Annäherung. Mittlerweile denke ich, dass die Logik hinter der Formel stimmt.

Außerdem wollte ich eine Lösung finden, die automatisch funktioniert und kein weiteres Verständnis für mögliche Ausnahmen erfordert. Dieses Ziel habe ich allerdings noch nicht umgesetzt.
Trotzdem will ich euch das vorläufige Ergebnis nun zeigen, der Zeitpunkt erscheint mir passend.

Ich habe das Ganze in Form einer Excel-Tabelle angelegt. Allerdings habe ich die Dokumentation vernachlässigt, deshalb wird es etwas dauern, alles wieder nachzuvollziehen. Die Erklärung für die einzelnen Schritte werde ich später hier nachliefern. Alles auf einmal zu schreiben wäre einfach zu viel.

Die angehängte Excel -Tabelle enthält 150 Zeilen mit Beispiel-Raumschüssen und einer kurzen Erklärung der einzelnen Spalten in der ersten Zeile.

Im nächsten Abschnitt wird es darum gehen, wo die alte Formel an ihre Grenzen stößt.


Edit: neue Version der Excel-Tabelle ersetzt die alte.

Das ist natürlich auch ein interessantes Thema. Es ist schön, dass du daran arbeitest.
Ich kann mir vorstellen, dass es schnell sehr kompliziert wird, wenn man in einer Höhle Ringschlüsse hat. Mit diesem Problem habe ich mich bisher nur wenig beschäftigt, deine Methode erscheint mir allerdings logisch.

Bei meiner Formel geht es jetzt nicht um die Darstellung von Messzügen, sondern um die Darstellung von Hilfszügen bzw. Raumschüssen.

Teil 2 - Warum überhaupt eine neue Formel?

Die alte Formel zur Berechnung des Datenfeldes Richtung für Raumschüsse lautet:

Richtung = cos(azimutMesslinie - azimutHilfslinie)

Wobei für azimutMesslinie immer der Azimut des vorherigen Messzuges verwendet wird.
azimutHilfslinie ist der Azimut des Raumschusses.

Ich möchte das Problem mit der alten Formel an einem Beispiel aufzeigen:

Teil 3 - Darstellung mit der neuen Formel

Beim Erstellen der Abbildung für meine neue Formel ist mir aufgefallen, dass die grünen Balken nun auf beiden Seiten nicht passen. Also habe ich erstmal nach Fehlern gesucht und bin mehrfach fündig geworden. Es hat etwas gedauert, aber ich konnte alle beheben. Die Darstellung hat sich mit der Fehlerbehebung zwar nur wenig geändert, aber immerhin ist eine Verbesserung erkennbar. Und eine richtige Formel ist besser als eine fast richtige Formel.

Die Fehlerbehebungen hatten aber noch einen anderen wichtigen Effekt. Die Formel bzw. Teilformeln sind deutlich kürzer und damit auch besser verständlich geworden.
Ich habe natürlich auch die oben in diesem Thread angehängte Excel-Tabelle aktualisiert.

Die grünen Balken passen zwar immer noch nicht exakt, aber zumindest ist die Darstellung nun näher dran. Ich überlege mir noch, wie das Ganze eventuell noch weiter verbessert werden könnte (z.B. mit 2x² oder einem ähnlichen Zusatz). Wie das gemeint ist, wird hoffentlich klar, wenn ich die Formel später erkläre.

Teil 4 - So funktioniert die Excel-Tabelle

In den Spalten A, B und C werden Daten aus der Vermessung per Hand eingetragen. Auf dieser Basis wird dann mit der neuen Formel ein Wert berechnet und in der Spalte M ausgegeben. Dieser Wert kann anschließend im Datenfeld Richtung in CaveRenderPro manuell eingetragen werden.

Um Missverständnisse zu vermeiden: Die Formel soll nur auf Raumschüsse (auch Hilfsmesszüge oder Hilfslinien genannt) angewandt werden, nicht jedoch auf Messzüge des Polygonzuges.


Man betrachtet jetzt also einen einzelnen Raumschuss.

In Spalte A wird eingetragen: Wert der Richtung (Azimut) des vorherigen Messzuges.
Es muss also erstmal festgestellt werden, welcher Messzug zu dem Messpunkt führt, von dem aus der Raumschuss gemessen wurde.
Im Beispiel von Abb. 1 bis 4 wäre das der Messzug von 1.25 nach 1.26.

In Spalte B wird eingetragen: Wert der Richtung (Azimut) des nachfolgenden Messzuges.
Es muss also erstmal festgestellt werden, welcher Messzug von dem Messpunkt wegführt, von dem aus der Raumschuss gemessen wurde.
Im Beispiel von Abb. 1 bis 4 wäre das der Messzug von 1.26 nach 1.27.

In Spalte C wird eingetragen: Wert der Richtung (Azimut) des Raumschusses.


In Spalte M gibt die neue Formel schließlich einen Wert als Ergebnis aus. Diesen kann man nun in CaveRenderPro in der Zeile des Raumschusses, den man betrachtet hat, in das Datenfeld Richtung eintragen.

Teil 5 - So funktioniert die neue Formel - Spalte E

In den Spalten E, G, K und L werden von der Excel-Tabelle automatisch Teilberechnungen der neuen Formel durchgeführt, nachdem der Nutzer Werte in die Spalten A, B und C eingegeben hat. Das Ergebnis wird in der Spalte M ausgegeben.


Spalte E enthält die Formel =ABS(ABS(A1-C1)-180) oder in alternativer Schreibweise ||A1-C1|-180|.

Das Ergebnis dieser Formel beschreibt den Winkel (in Grad) zwischen der invertierten Richtung (Azimut) des vorherigen Messzuges und der Richtung (Azimut) des Raumschusses.
Das Ergebnis beantwortet also die Frage: Wie sehr weicht der Raumschuss vom vorherigen Messzug ab?

A1 und C1 habe ich bereits erklärt. ABS bedeutet, dass der Betrag genommen wird.

Die Reihenfolge der Berechnungen sieht so aus: A1-C1 > ABS > -180 > ABS.

Wenn der Raumschuss exakt in Richtung des vorherigen Messpunktes zeigt, ist das Ergebnis 0.
Wenn der Raumschuss in die exakt gleiche Richtung wie der vorherige Messzug zeigt, ist das Ergebnis 180.
Alle möglichen Ergebnisse können nur Werte zwischen 0 und 180 annehmen.

Die Formel ist in der Lage, den korrekten Winkel zu berechnen, auch wenn man Werte wie 359 und 1 nimmt. Der korrekte Winkel ist nämlich 178 und nicht 358 oder 2.

Eine alternative Berechnungsmethode, die das gleiche Ergebnis erhält, lautet: =180-(WENN(ABS(A1-C1)<=180;ABS(A1-C1);180-(ABS(180-(ABS(A1-C1)))))).

Danke, es freut mich, dass dir die Lösung gefallen hat.

Zitat von CaveRenderPro im Beitrag #9

---

Die neue Formel stellt eine gute Ergänzung für die nach hinten laufenden Hilfslinien dar.

---

Zitat von CaveRenderPro im Beitrag #9

---

Brauchen wir eine solche Funktion in CaveRenderPro selbst?

---

Teil 6 - So funktioniert die neue Formel - Spalte G

Spalte G enthält die Formel =ABS(ABS(WENN(B1-180>0;B1-180;B1+180)-C1)-180)
Allerdings ist mir mittlerweile aufgefallen, dass man das auch kürzer schreiben kann.

Spalte G sollte eigentlich die Formel =ABS(ABS(ABS(B1-C1)-180)-180) enthalten. Oder in alternativer Schreibweise |||B1-C1|-180|-180|.

Das Ergebnis dieser Formel beschreibt den Winkel (in Grad) zwischen der Richtung (Azimut) des nachfolgenden Messzuges und der Richtung (Azimut) des Raumschusses.
Das Ergebnis beantwortet also die Frage: Wie sehr weicht der Raumschuss vom nachfolgenden Messzug ab?
Diese Formel funktioniert ähnlich, wie die in Spalte E.

B1, C1 und ABS habe ich bereits erklärt.

Die Reihenfolge der Berechnungen sieht so aus: B1-C1 > ABS > -180 > ABS > -180 > ABS.

Wenn der Raumschuss exakt in Richtung des nachfolgenden Messpunktes zeigt, ist das Ergebnis 0.
Wenn der Raumschuss in die exakt gegen gerichtete Richtung wie der nachfolgende Messzug zeigt, ist das Ergebnis 180.
Alle möglichen Ergebnisse können nur Werte zwischen 0 und 180 annehmen.

Teil 7 - So funktioniert die neue Formel - Spalte K

Mit den Ergebnissen der Berechnungen in den Spalten E und G wird nun in Spalte K weitergerechnet.

Spalte K enthält die Formel =WENN(ODER(E1=0;G1=0);0;WENN(E1/G1<=1;E1/(E1+G1);G1/(G1+E1))).

Das Ergebnis dieser Formel beschreibt den kleineren von zwei Anteilen (in Prozent). Dieser Anteil errechnet sich aus dem Verhältnis zwischen den Werten in E1 und G1.
Das Ergebnis beantwortet die Frage: Zu wie viel Prozent sollte der Messzug, der weiter vom Raumschuss abweicht in die Berechnung des Endergebnisses einfließen.

Die Formel besteht aus zwei Teilen. Der äußere sieht so aus: =WENN(ODER(E1=0;G1=0);0;Sonst_Wert)
Das bedeutet, wenn entweder in Spalte E oder Spalte G eine 0 steht, ist das Ergebnis ebenfalls 0.
Also wenn der Raumschuss exakt in die Richtung eines der beiden benachbarten Messpunkte zeigt, fließt die Richtung des anderen Messpunktes zu 0% in die Berechnung des Endergebnisses ein.

Sollte dieser Fall nicht eintreten, wird mit der Berechnung fortgefahren.

Der innere Teil sieht so aus: WENN(E1/G1<=1;E1/(E1+G1);G1/(G1+E1))
Zunächst wird hier geprüft, ob E1 geteilt durch G1 kleiner oder gleich 1 ist.

Wenn E1/G1 gleich 1 ist, bedeutet das, dass beide Werte identisch sind. Also ist der Raumschuss genau zwischen den beiden Messzügen und die Formel E1/(E1+G1) gibt den Wert 0,5 aus. Beide Messzüge fließen so zu gleichen Teilen in das Endergebnis ein.

Wenn E1/G1 kleiner als 1 ist, bedeutet das, dass E1 kleiner als G1 ist. Der Raumschuss ist also weiter vom nachfolgenden Messzug entfernt, sodass dieser weniger ins Endergebnis einfließt. Die Formel E1/(E1+G1) wird dann einen Wert kleiner als 0,5 ausgeben.

Wenn E1/G1 <= 1 nicht stimmt, ist E1 logischer Weise größer als G1 und es wird stattdessen die Formel G1/(G1+E1) verwendet, die ebenfalls einen Wert kleiner als 0,5 ausgibt. Der Raumschuss ist in diesem Fall weiter vom vorherigen Messzug entfernt, sodass dieser weniger ins Endergebnis einfließt.

Alle möglichen Ergebnisse können nur Werte zwischen 0 und 0,5 annehmen.

Zusammengefasst kann man sagen, dass die Formel so konzipiert wurde, dass der kleinere Wert durch die Summe der beiden Werte geteilt wird.

Teil 8 - So funktioniert die neue Formel - Spalte L


Mit den Ergebnissen der Berechnungen in den Spalten E, G und K wird nun in Spalte L weitergerechnet.

Spalte L enthält die Formel =WENN(E1<G1;K1*COS(BOGENMASS(B1-C1))+(1-K1)*COS(BOGENMASS(A1-C1));K1*COS(BOGENMASS(A1-C1))+(1-K1)*COS(BOGENMASS(B1-C1)))

Als erstes haben wir eine Fallunterscheidung: =WENN(E1<G1;Dann_Wert;Sonst_Wert)

Wenn E1 kleiner als G1 ist, weicht der nachfolgende Messzug weiter vom Rauschuss ab und wird somit dem Wert aus K1 zugewiesen. Der vorherige Messzug bekommt in diesem Fall den Wert (1-K1) zugewiesen, der immer größer oder gleich dem Wert von K1 ist. Denn K1 kann ja nur Werte zwischen 0 und 0,5 annehmen. Damit kann (1-K1) nur Werte zwischen 0,5 und 1 annehmen.
K1 + (1-K1) ist logischerweise immer 1.

In diesem Fall wird berechnet: K1*COS(BOGENMASS(B1-C1))+(1-K1)*COS(BOGENMASS(A1-C1)). Das entspricht dem Dann_Wert.

bzw. A1 und B1 sind vertauscht, wenn E1 nicht kleiner als G1 ist.

In dem Fall sieht es so aus: K1*COS(BOGENMASS(A1-C1))+(1-K1)*COS(BOGENMASS(B1-C1)). Das entspricht dem Sonst_Wert.


Ein Beispiel: E1=50 G1=10
E1 ist größer, also weicht der vorherige Messzug mehr von der Richtung des Raumschusses ab. Wir nehmen den Sonst_Wert.
K1 ist der kleinere Wert geteilt durch die Summe beider Werte. Also 10/(50+10)=1/6
L1 = 1/6*COS(BOGENMASS(A1-C1))+5/6*COS(BOGENMASS(B1-C1))

Spalte M enthält die Formel =RUNDEN(L1;2)

Das Ergebnis aus der Spalte L wird also nur noch auf 2 Nachkommastellen gerundet und fertig ist das neue Endergebnis, das in CaveRenderPro eingetragen werden kann.

Teil 9 - Weitere Spalten

Die Excel-Tabelle enthält 5 weitere Spalten (D, F, N, O, P).

Spalte D enthält die Formel =RUNDEN(COS(BOGENMASS(A1-C1));2)

Das ist die alte Formel, bei der nur der vorherige Messzug in die Berechnung einfließt.
Sie findet Anwendung, wenn es keinen nachfolgenden Messzug gibt, also überall dort, wo in der Höhle ein Ende erreicht wird.

Spalte F enthält die Formel =RUNDEN(COS(BOGENMASS(B1-C1));2)

Das ist wieder die alte Formel, allerdings mit dem Unterschied, dass hier nur der nachfolgende Messzug in die Berechnung einfließt.
Sie findet Anwendung, wenn es keinen vorherigen Messzug gibt, z.B. am Eingang der Höhle.

Spalte N enthält die Formel =ABS(M1-D1)

Diese Spalte zeigt die Differenz zwischen alter und neuer Formel, was einfach nur zur Veranschaulichung dient. Sie kann Werte zwischen 0 und 2 annehmen.

Ein kleines Gedankenspiel:
Das zeigt auch, dass der größte Fehler der alten Formel 2 wäre. Er würde dann auftreten, wenn die Richtung des nachfolgenden Messzuges der Richtung des vorherigen Messzuges exakt entgegen gerichtet ist und der Raumschuss exakt in die Richtung des nachfolgenden Messzuges zeigt. Das kann zwar vorkommen, wird aber im Längsschnitt anders gezeichnet. Der nachfolgende Messzug und der Raumschuss werden einfach invertiert. Daher ist der Fehler der alten Formel in diesem Sonderfall 0.


Spalte O enthält die Formel =WENN(D1=M1;0;WENN(F1=M1;0;WENN(UND(L1<D1;L1<F1);100;WENN(UND(L1>D1;L1>F1);100;0))))
Besser, weil kürzer wäre die Formel =WENN(UND(M1<D1;M1<F1);100;WENN(UND(M1>D1;M1>F1);100;0))

Diese Formel war nützlich, um während des Entwicklungsprozesses der neuen Formel mögliche Fehler schnell zu erkennen. Für den Benutzer hat sie keine Verwendung mehr.
Die Fehlerprüfung gibt 0 aus, wenn kein Fehler entdeckt wurde, sonst 100.

Hier wird überprüft, ob der Wert der neuen Formel außerhalb des Bereiches zwischen den 2 Varianten der alten Formel in den Spalten D und F liegt. Logisch gesehen kann das nämlich nicht passieren und würde daher auf einen Fehler in der neuen Formel hinweisen.

Ein Fehler würde entdeckt werden, wenn das Ergebnis der neuen Formel geringer/größer wäre als die beiden Ergebnisse der 2 Varianten der alten Formel.

Teil 10 - Spalte P - Erster Sonderfall

Während der Entwicklungsphase der neuen Formel ist bei mir recht früh ein Sonderfall aufgetreten.
Obwohl bereits die funktionierende neue Formel verwendet wurde, ergab die Darstellung wenig Sinn.



Abb. 5: Grundriss: Zwischen den Punkten 22 und 25 verläuft der Gang bei gleichbleibenden Dimensionen geradeaus.
Allerdings wird bei den Punkten 23 und 24 eine 3m-Schachtstufe umgangen und gleichzeitig ein kleiner Schacht eingemessen.
Dadurch entsteht an dieser Stelle ein Knick. Man könnte es auch ein " Z " nennen.



Abb. 6: In der 3D-Perspektive kann man sich die Stelle von der Seite ansehen. Man kann erkennen, dass die Decke dieses Ganges gleichbleibend ansteigt und keinerlei Stufen aufweist.



Abb. 7: Wenn man sich jetzt aber die Darstellung im Längsschnitt anschaut, nachdem bereits die neue Formel angewandt wurde, merkt man eine deutliche Diskrepanz.
Die Decke über dem Punkt 24 sieht deutlich höher aus als in der 3D-Ansicht. Besonders der farblich in Lila hervorgehobene Raumschuss wirkt deplatziert.

Das liegt daran, dass die Darstellung im Kontext der Messpunkte 23, 24 und 25 zwar korrekt ist, aber im Kontext des gesamten Ganges zwischen den Messpunkten 22 und 25 ist es eben nicht mehr stimmig (siehe Abb. 5).



Abb. 8: Und nun zur Lösung. Um den Gang an dieser Stelle wirklich sinnvoll zeichnen zu können, muss man das " Z " als Sonderfall behandeln. Dazu berechnet man mit der neuen Formel einen Wert für das Datenfeld Richtung des Messzuges 23 nach 24, als ob dieser ein Raumschuss wäre. Als vorherigen Messzug verwendet man 22 nach 23 und als nachfolgenden Messzug 24 nach 25. Darüber hinaus behandelt man die Raumschüsse, die von Messpunkt 24 abgehen, als ob es den Messzug 23 nach 24 nicht gäbe und der vorherige Messzug eigentlich 22 nach 23 wäre. Man berechnet die Werte für das Datenfeld Richtung der Raumschüsse wieder mit der neuen Formel.

Oder mit anderen Worten: Im Längsschnitt spielt Richtung für die Messzüge eigentlich keine Rolle, nur Länge und Neigung zählt. Aber hier machen wir eine Ausnahme, damit der Höhlenplan sinnvoll gezeichnet werden kann.


Deswegen stellte sich mir die Frage, ob und wie man solche Situationen automatisch erkennen könnte. So kam die Spalte P in die Excel-Tabelle.

Spalte P enthält die Formel =WENN(ABS(ABS(A2-B2)-180)<90;100;0)

Das Ergebnis dieser Formel ist 100, wenn möglicherweise eine derartige Situation vorliegt und 0 wenn nicht.
Das Ergebnis beantwortet die Frage: Ist der Winkel zwischen den beiden Messzügen kleiner als 90 Grad? Dann bestünde die Gefahr, dass dieser Sonderfall auftritt.

In der Praxis ist diese Situation aber nur dieses eine Mal aufgetreten und seither nicht mehr (bei über 1000 Messungen!). Und die Formel produziert haufenweise falsche Treffer. Damit ist sie kaum hilfreich, eher maximal verwirrend. Auch der Grenzwert von 90 Grad wirkt eher zufällig und ist für mich nicht mehr nachvollziehbar.

Ich habe den Eindruck, es ist mal wieder Zeit, eine neue, bessere Version der Excel-Tabelle hochzuladen, denn seitdem ich hier angefangen habe zu schreiben, hat sich doch wieder einiges geändert und zumindest die letzten 2 Spalten sind obsolet geworden. Habe eine neue Version angehängt.


Die Frage, wie CaveRenderPro zukünftig eine solche Ausnahme automatisch erkennen kann, bleibt offen.
Dazu kann ich nur sagen, ich glaube nicht, dass es in näherer Zukunft eine derartige Möglichkeit geben wird. Das wird auch weiterhin der Nutzer selbst erkennen müssen.

Was aber geht ist, dass der Nutzer einem Messzug einen Wert im Datenfeld Richtung ungleich 1 oder -1 zuweist, was genau auf die beschriebene Situation hindeutet. Dann kann CaveRenderPro dies erkennen und entsprechend reagieren.

Wie genau das geht und weitere Faktoren, die für die Implementierung wichtig werden, erkläre ich im nächsten Teil.